問：
您好，腳本專家！我女兒有一種閃卡式程序，它能夠獲取文本文件中的單詞列表。我如何編寫一個腳本，使其能夠打開該文件并自動打亂單詞列表的順序呢？
-- SN
答：
您好，SN。您知道，大多數(shù)情況下，我們盡力使此專欄關注實際的系統(tǒng)管理任務：我們告訴您如何設置默認打印機、如何禁用服務以及如何映射網(wǎng)絡驅動器。不過，有時我們也愿意處理那種聽起來就很有趣的問題，而最終的結果有多大用處我們是不會去考慮的。系統(tǒng)管理員通常需要打亂文本文件中單詞列表的順序嗎？可能不需要。但是，若是只工作，不玩耍，想必聰明的小孩也會變傻，對不對？
實際上，有些小孩就算玩了也還是有點傻。但這是另外一回事。
明確這一點后，讓我們看一下可以打亂文本文件中單詞順序的腳本。正如我們說過的那樣，這樣的工作在實際當中可能沒有一點用處，但它是有點挑戰(zhàn)性，并且也確實需要我們使用一點令人感興趣的腳本編寫小竅門。還有，如果不是這樣，您可能永遠也不會知道這樣的竅門何時才能派上用場。
首先，假定您有個類似于下面這樣的文本文件，文件中的所有單詞按字母順序排列：
Apple
Banana
Carrot
Dog
Fish
Elephant
Giraffe
Horse
如何才能打亂這些詞的順序呢？使用像下面這樣的腳本即可：
復制代碼 代碼如下:
Const ForReading = 1
Const ForWriting = 2
Set objDictionary = CreateObject("Scripting.Dictionary")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("c:\scripts\words.txt", ForReading)
i = -1
Do Until objFile.AtEndOfStream
strLine = objFile.Readline
objDictionary.Add strLine, strLine
i = i + 1
Loop
objFile.Close
Dim arrWords()
Redim arrWords(i)
intWordsLeft = i
z = 0
Do While intWordsLeft >= 0
Randomize
rndWord = Int((intWordsLeft - 0 + 1) * Rnd + 0)
intWordsLeft = intWordsLeft - 1
colItems = objDictionary.Items
strText = colItems(rndWord)
arrWords(z) = strText
z = z + 1
objDictionary.Remove(strText)
Loop
Set objFile = objFSO.OpenTextFile("c:\scripts\words.txt", ForWriting)
For Each strItem in arrWords
objFile.WriteLine strItem
Next
objFile.Close
哦，當然，這看起來有些不可思議；確實是件不可思議的差事（至少對系統(tǒng)管理員來講是這樣的）。但是，不管您相信與否，這其中是有邏輯的，我們也將逐步讓您明白這種邏輯。
腳本的第一部分確實相當簡單。我們定義一對常量 - ForReading 和 ForWriting，我們將在處理文本文件時使用這兩個常量。然后創(chuàng)建兩個對象：Scripting.Dictionary 和 Scripting.FileSystemObject。我們將使用 Dictionary 對象作為從文本文件中所讀取單詞的臨時倉庫；而使用 FileSystemObject 與該文本文件進行實際的交互。
接下來使用 OpenTextFile 方法打開文件 C:\Scripts\Words.txt 以進行讀取。（注意常量 ForReading 的使用。）下一步，創(chuàng)建一個計數(shù)器變量 i 并將其值設置為 -1；我們將使用此變量跟蹤文件中的單詞數(shù)。為什么 i 要從 -1 而不是 0 開始？因為我們要使用 i 建立一個數(shù)組，并且由于數(shù)組中的第一項始終為 0（而不是 1），因此我們需要從 -1 開始。在我們讀取第一個單詞時，i 將被設置為 0，盡管聽起來有些奇怪，但是大小為 0 的數(shù)組意味著該數(shù)組中包含一個數(shù)據(jù)項。
嗨，我們只是如實匯報，至于原因我們可不曉得。
接下來是下面這段代碼：
復制代碼 代碼如下:
Do Until objFile.AtEndOfStream
strLine = objFile.Readline
objDictionary.Add strLine, strLine
i = i + 1
Loop
我們在這里所做的就是逐行讀取文件。對于文件中的每一行（即每個單詞），我們將該值賦給一個名為 strLine 的變量；隨后使用 Add 方法將該值添加到 Dictionary 對象之中，從而將 i 值加 1。文件讀取結束之后，所有的單詞都存儲在 Dictionary 對象之中，i 的值將為 7，這恰好是文件中的單詞數(shù)減 1。（為什么？因為其中含有 8 項數(shù)據(jù)的數(shù)組的大小為 7。）
別擔心；到最后您應該會明白其原因所在。
我們希望如此。
關閉文件之后，初始化數(shù)組 arrWords，設置其大小為 i （表示文本文件中的單詞數(shù)減 1）。同時將 i 值賦給變量 intWordsLeft，通過它我們將知道有多少單詞要被打亂順序。最后，將變量 z 的值設為 0；我們將使用 z 將已打亂順序的單詞填充到數(shù)組中。實際上，我們要做的就是從 Dictionary 中隨機取出一個單詞然后將其添加到數(shù)組中。因為單詞是以隨機的順序從 Dictionary 中取出的，因此它們在數(shù)組中的順序將被“打亂”（以不同的順序存儲）。
現(xiàn)在，到了很有趣的這部分。建立一個 Do 循環(huán)，其一直運行到我們用完 Dictionary 對象中的所有單詞。接著使用下面這兩行代碼從 0 和 Dictionary 對象中數(shù)據(jù)項的數(shù)目（或者至少是數(shù)據(jù)項的實際數(shù)減 1，因為 Dictionary 對象中的第一個數(shù)據(jù)項為第 0 項）之間隨機選擇一個數(shù)字：
Ranndomize
rndWord = Int((intWordsLeft - 0 + 1) * Rnd + 0)
之后我們將 intWordsLeft 值減 1；這樣做是為了始終記住我們現(xiàn)在要處理的單詞比之前所處理的少了一個。
那么我們需要這個隨機數(shù)字做什么呢？我們現(xiàn)在要做的就是使用該值從 Dictionary 中隨機抽取一個單詞。為此，我們可以創(chuàng)建一個 Dictionary 項的集合，然后在變量 strText 中存儲此隨機選擇的數(shù)據(jù)項數(shù)字的值：
colItems = objDictionary.Items
strText = colItems(rndWord)
換句話說，Banana 當前為 Dictionary 中的第 1 項。假定在生成隨機數(shù)字的時候得到的是 1。這意味著我們將從 Dictionary 中將第 1 項的值取出；然后，也就意味著單詞 Banana 被存儲在變量 strText 中。
明白了嗎？從 Dictionary 中隨機取出一個單詞之后，我們即需要將該值存儲到某個地方。為此我們使用數(shù)組 arrWords，使 strText 成為數(shù)組中的第一項：
Words(z) = strText
我們如何知道該值應成為第一項？因為我們將該值賦給第 z 項，而第 z 項等于 0。之后，我們立即將 z 加 1，z 將等于 1。這也意味著，通過循環(huán)下一次我們會將檢索到的值賦給數(shù)組中的第二項。
單詞 Banana 使用過之后，下一步就是將該單詞從 Dictionary 中刪除；否則我們可能會再次使用該單詞。要刪除此單詞，只需調用 Dictionary 對象的 Remove 方法，將變量 strText 作為要刪除的項進行傳遞即可：
objDictionary.Remove(strText)
一切均順利完成之后，數(shù)組 arrWords 將包含一個從文本文件中所取出的已打亂順序的單詞的列表：
Banana
Elephant
Giraffe
Apple
Fish
Carrot
Horse
Dog
很好，是吧？隨后我們只要打開文件 Words.txt（這次是進行寫入），然后使用已打亂順序的列表 arrWords 替換現(xiàn)有內容即可：
復制代碼 代碼如下:
Set objFile = objFSO.OpenTextFile("c:\scripts\words.txt", ForWriting)
For Each strItem in arrWords
objFile.WriteLine strItem
Next
objFile.Close
下次您的女兒（誰的女兒都一樣）運行教育程序的時候，她所看到的將是以隨機方式顯示的單詞。
順便說一句，我們并沒有像人們所謠傳的那樣對此專欄的文本進行了該腳本的測試。在您好，腳本專家！專欄中的單詞可不是隨機選擇的；每個單詞都是我們花了無數(shù)的時間進行辛勤的探索和耕耘所得到的。
事實上，就在我們做完所有認真細致的耕耘之后。我們的編輯又將所有單詞的順序隨機打亂。如果您能看到該專欄編輯之前的樣子，就一定會為它的美妙而吃驚不已?。ň庉嫺阶ⅲ耗吹降臅沁@種編輯之前的情況：將您吃驚感到。使用不會但是單詞這個我“美妙”。）
